Problem 2

Define a helper function f(i) for the sum.
We need to prove a closed form for   g(n) = (∑_(i = 1)^( n)) f(i).

Clear[f,g,n]
f[i_] :=  1/((3i-2)(3i+1));

In this case, Mathematica can evaluate the sum symbolically and find the closed form.

Sum[ f[i], {i,n}]
% // Simplify

Still, we need a proof.  Define g to be the last function.

g[n_] := n/(3n+1);

Check for n=0:

g[0]

Induction comes down to this:  show 
	g(n+1) = f(n+1) + g(n). 
The variable n here is free, it has no particular value.

g[n+1] == f[n+1] + g[n]
% // Simplify

Done.  Except that for homework you need to show the steps.

Problem 3

Again, define a helper function f(i) , this time for the product.
We need to figure out  g(n) = (Subscript[∏ , i =2]^( n)) f(i).

Clear[f,g,n]
f[i_] :=  1 - (-1)^i/i;

Mathematica can evaluate the product symbolically, but it uses Euler’s  Γ function for this purpose. 
Very impressive, but useless for 151.

Product[ f[i], {i,2,n}] // TraditionalForm

We need a more pedestrian approach.

Table[ {n,Product[ f[i],{i,2,n}]}, {n,2, 12}] // TableForm

Much better.  For even n, the result is 1/2, and for odd n, ⌈n/2⌉/n. 
For the proof.  Define g to be this function.

g[n_] := 1/2     /;  EvenQ[n];
g[n_] := Ceiling[n/2]/n;

Sanity check:

g /@ Range[2,12]

The induction is a bit messier.  For even n, we need 
	 g(n)  f(n+1) f(n+2) = 1/2 . 
To express that n is even we write n = 2m.

res = g[2m]f[2m+1]f[2m+2]

We need to tell the system that m is an integer:

Simplify[ res, m ∈ Integers ]

For odd n, we need 
	 g(n)  f(n+1) f(n+2) = g(n+2) . 
To express that n is even we write n = 2m.

res = g[2m+1]f[2m+2]f[2m+3]

Simplify[ res, m ∈ Integers ]

Done.  If you trust the simplification procedure, this is a complete proof.

Problem 6

Warning:  Mathematica uses 1-indexing for sequences, so everything here is shifted over by 1.

We leave (Subscript[a, 1]) and (Subscript[a, 2]) unspecified.

Clear[a,a1,a2,n]

tab = RecurrenceTable[{a[n]==2a[n-1]+3a[n-2],a[1]==a1,a[2]==a2},a, 
  {n,10}] // Simplify;
tab // TableForm

So  (Subscript[a, n])= (Subscript[b, n])(Subscript[a, 1])+ (Subscript[c, n])(Subscript[a, 2])  and we need to figure out what the coefficients are. 
Brute force:

coeffb =Last/@ (PadRight[CoefficientList[#,a1],2]& /@ tab)
coeffc=Last/@ (PadRight[CoefficientList[#,a2],2]& /@ tab)

In this case, we can immediately obtain a closed form (which can be proven by induction):

FindSequenceFunction[ coeffb, z ]
FindSequenceFunction[ coeffc, z ]

This can be simplified slightly to 
	(Subscript[b, n])= 1/4((3^(n-1))+3(((-1))^(n-1)))
	(Subscript[c, n])= 1/4((3^(n-1))-(((-1))^(n-1)))
Hence  (Subscript[c, n])- (Subscript[b, n])= (((-1))^n) and exactly one of the coefficients is odd. 
That takes care of claim 1. 

For claim 2 we have  (Subscript[a, n])= (Subscript[b, n])+ (Subscript[c, n ])= 1/2( (3^(n-1))+ (((-1))^(n-1))) .