mode 0
menu "Add-On Scripts"
name "Watermark Translucency"
label "Watermark Translucency"

##########################################################################
##									##
##   TRANSLUC.CSM    Select waternark opacity				##
##   Public Domain by Ralf Brown <ralf@pobox.com>			##
##		      815 Copeland Way PMB 26				##
##		      Pittsburgh, PA 15232				##
##		      USA						##
##   Version 1.0							##
##   Last Edit 13nov99							##
##									##
##   Target Devices: Kodak DC290			 		##
##	(developed and tested on a DC290)				##
##									##
##   Documentation							##
##   =============							##
##									##
##   Install by copying to the \SYSTEM folder on your flash card	##
##   (either using a card reader or the Mounter).  When using a		##
##   card reader or PCMCIA slot, be sure to use an ALL-CAPS filename,	##
##   as some Kodak models have been known to lock up when there are	##
##   MSWindows long file names on the card.  The script places		##
##   itself in the Advanced Exposure Modes menu in Capture mode.	##
##									##
##                                                                      ##
##   Known Limitations                                                  ##
##   =================                                                  ##
##                                                                      ##
##   Availability							##
##   ============							##
##   The newest version of this script is always available at		##
##   www.digitacamera.com.						##
##									##
##########################################################################

declare u:u_ret, u_value, uVarType
declare u:uEnumCount, uEnumDefault, uEnumValue
declare u:count
declare u:hint
declare u:choice, u_current
declare i:status
declare s:sPrompt, sVarName, sEnumDesc

   sPrompt = "Use Current Text Opacity"
   sVarName = "wsop"
   u_ret = 100
   goto AskEnum
ret_100:

   sPrompt = "Use Current Date/Time Opacity"
   sVarName = "wtop"
   u_ret = 101
   goto AskEnum
ret_101:

   exitscript

##########################################################################

AskEnum:
   #
   # verify that the requested variable actually exists
   #
   status = 0
   status = GetCapabilityType(sVarName,uVarType)
   if status != 0
      # setting not supported on this camera....
      Alert("This camera does not support setting font sizes")
      goto error
   end
   status = GetCameraState(sVarName,u_current)
   GetCapabilitiesCount(sVarName, uEnumCount, uEnumDefault)
   if uEnumCount == 0
      u_value = u_current
   end
   if uEnumCount != 0
      #
      # get the user's choice; start by displaying a menu containing the
      #   valid values
      #
      DisplayClear()
      SetOption(u_current,sPrompt)
      count = 0
enum_loop:
	 GetCapabilitiesListItem(sVarName,count,sEnumDesc,uEnumValue)
	 SetOption(uEnumValue,sEnumDesc, uEnumValue == u_current)
	 count = count + 1
	 if count < uEnumCount
	    goto enum_loop
	 end
	 #end of loop 'enum_loop'
      #
      # We've built the menu of choices for the user, so find out what the
      #   user wants
      #
      GetOption(u_value)
   end
   SetCameraState(sVarName,u_value)

   if u_ret == 100
      goto ret_100
   end
   if u_ret == 101
      goto ret_101
   end
   Alert("Programming Error: missed return case in AskEnum")

error:
   Wait(50)
   exitscript

#########################################################################
#				End of File				#
#########################################################################