mode 1
menu "Add-On Scripts"
name "Camera Information"
label "Camera Information"

######################################################################
##								    ##
##   Camera Information 					    ##
##								    ##
##   Public Domain by Ralf Brown, 08nov98			    ##
##								    ##
######################################################################

declare u: choice, uCCDPat, uHPix, uVPix, uCCDHRing, uCCDVRing
declare u: uCCDBadCol, uCCDBadRow, uType, uSize, uHCnt, uVCnt, uHOrg, uVOrg
declare u: uZone

MenuLoop:
# Find out what to report
   SetOption (1, "CCD", 0)
   SetOption (2, "Thumbnail", 0)
   SetOption (3, "Screennail", 0)
   SetOption (4, "Focus", 0)
   SetOption (5, "Exposure", 0)
   GetOption (choice)
   if choice == 1
     goto ReportCCD
   end
   if choice == 2
     goto ReportThumb
   end
   if choice == 3
     goto ReportScreen
   end
   if choice == 4
     goto ReportFocus
   end
   if choice == 5
     goto ReportExposure
   end
   goto MenuLoop

ReportCCD:
   GetImageSpecifications(1,"ptrn",uCCDPat)
   GetImageSpecifications(1,"hpix",uHPix)
   GetImageSpecifications(1,"vpix",uVPix)
   GetImageSpecifications(1,"rhpx",uCCDHRing)
   GetImageSpecifications(1,"rvpx",uCCDVRing)
   GetImageSpecifications(1,"bcol",uCCDBadCol)
   GetImageSpecifications(1,"brow",uCCDBadRow)

   DisplayClear()
   DisplayLine("CCD Info")
   DisplayLine(uHPix, "x", uVPix, " pixels, pat#", uCCDPat)
   DisplayLine(uCCDHRing, "x", uCCDVRing, " ring pixels")
   DisplayLine("Bad: ", uCCDBadCol, " cols, ", uCCDBadRow, " rows")
   Wait(4000)
   goto MenuLoop

ReportThumb:
   GetImageSpecifications(2,"ttyp",uType)
   GetImageSpecifications(2,"hpix",uHPix)
   GetImageSpecifications(2,"vpix",uVPix)
   GetImageSpecifications(2,"fsiz",uSize)

   DisplayClear()
   DisplayLine("Thumbnail Info")
   DisplayLine(uHPix, "x", uVPix, " pixels")
   DisplayLine(uSize, " bytes")
   Display("Format = ")
   if uType == 4
      DisplayLine("YCC 422")
   end
   if uType != 4
      DisplayLine("type ",uType)
   end
   Wait(4000)
   goto MenuLoop

ReportScreen:
   GetImageSpecifications(3,"styp",uType)
   GetImageSpecifications(3,"hpix",uHPix)
   GetImageSpecifications(3,"vpix",uVPix)

   DisplayClear()
   DisplayLine("Screennail Info")
   if uType == 0
      DisplayLine("no screennails")
   end
   if uType
      if uType == 1
	 DisplayLine("JPEG Compressed")
      end
      if uType != 1
	 DisplayLine("Type ", uType)
      end
      DisplayLine(uHPix, "x", uVPix, " pixels")
   end
   Wait(4000)
   goto MenuLoop

ReportFocus:
   DisplayClear()
   DisplayLine("Focus Zones")
   uZone = 4
   goto ReportZones

ReportExposure:
   DisplayClear()
   DisplayLine("Exposure Zones")
   uZone = 5
   #goto ReportZones

ReportZones:
   GetImageSpecifications(uZone,"ztyp",uType)
   GetImageSpecifications(uZone,"hcnt",uHCnt)
   GetImageSpecifications(uZone,"vcnt",uVCnt)
   GetImageSpecifications(uZone,"horg",uHOrg)
   GetImageSpecifications(uZone,"vorg",uVOrg)
   GetImageSpecifications(uZone,"hsiz",uHPix)
   GetImageSpecifications(uZone,"vsiz",uVPix)

   if uType == 0
      DisplayLine("none")
   end
   if uType
      if uType == 1
	 DisplayLine("rectilinear array")
      end
      if uType != 1
	 DisplayLine("Zone Type ",uType)
      end
      DisplayLine(uHCnt, "x", uVCnt, " zones of")
      DisplayLine(uHPix, "x", uVPix, " pixels")
      DisplayLine("origin is (", uHOrg, ",", uVOrg, ")")
   end
   Wait(4000)
   goto MenuLoop

   exitscript