#!/bin/csh
#
#  Run a set of otter jobs ($1/*.in) and compare the
#  results ($1/*.out) to $1/*.486.
#

cd $1
set errors=0
foreach i (*.in)
  echo "Running $1/$i ..."
  ../../source/otter < $i >& $i:r.out
  if (-e $i:r.486) then
    set gen486=`grep "clauses generated" $i:r.486 | awk '{print $3}' | tail -1`
    set gennew=`grep "clauses generated" $i:r.out | awk '{print $3}' | tail -1`
    if ($gennew != $gen486) then
      echo "There is a problem: your computer generated $gennew, McCune's generated $gen486"
      set errors=1
    else
      echo "Okay, it seems to have run correctly."
    endif
  else
    echo "Okay, but there's no file for comparison."
    set errors=1
  endif
end

echo ""

if (! $errors) then
  set time486=`grep "user CPU time" *.486 | awk '{sum += $4} END {print sum}'`
  set timenew=`grep "user CPU time" *.out | awk '{sum += $4} END {print sum}'`
  set speedup=`awk "END {print $time486 / $timenew}" /dev/null`
  echo "timenew=$timenew, time486=$time486."
  echo "This computer runs Otter about $speedup times as fast as McCune's 486."
endif

echo "The output files have been left in $1/*.out."
echo ""

cd ..
